Tệp văn bản
src/runtime/sys_linux_mipsx.s
1 // Copyright 2016 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //go:build linux && (mips || mipsle)
6
7 //
8 // System calls and other sys.stuff for mips, Linux
9 //
10
11 #include "go_asm.h"
12 #include "go_tls.h"
13 #include "textflag.h"
14
15 #define SYS_exit 4001
16 #define SYS_read 4003
17 #define SYS_write 4004
18 #define SYS_open 4005
19 #define SYS_close 4006
20 #define SYS_getpid 4020
21 #define SYS_kill 4037
22 #define SYS_brk 4045
23 #define SYS_mmap 4090
24 #define SYS_munmap 4091
25 #define SYS_setitimer 4104
26 #define SYS_clone 4120
27 #define SYS_sched_yield 4162
28 #define SYS_nanosleep 4166
29 #define SYS_rt_sigreturn 4193
30 #define SYS_rt_sigaction 4194
31 #define SYS_rt_sigprocmask 4195
32 #define SYS_sigaltstack 4206
33 #define SYS_madvise 4218
34 #define SYS_mincore 4217
35 #define SYS_gettid 4222
36 #define SYS_futex 4238
37 #define SYS_futex_time64 4422
38 #define SYS_sched_getaffinity 4240
39 #define SYS_exit_group 4246
40 #define SYS_timer_create 4257
41 #define SYS_timer_settime 4258
42 #define SYS_timer_settime64 4409
43 #define SYS_timer_delete 4261
44 #define SYS_clock_gettime 4263
45 #define SYS_tgkill 4266
46 #define SYS_pipe2 4328
47
48 TEXT runtime·exit(SB),NOSPLIT,$0-4
49 MOVW code+0(FP), R4
50 MOVW $SYS_exit_group, R2
51 SYSCALL
52 UNDEF
53 RET
54
55 // func exitThread(wait *atomic.Uint32)
56 TEXT runtime·exitThread(SB),NOSPLIT,$0-4
57 MOVW wait+0(FP), R1
58 // We're done using the stack.
59 MOVW $0, R2
60 SYNC
61 MOVW R2, (R1)
62 SYNC
63 MOVW $0, R4 // exit code
64 MOVW $SYS_exit, R2
65 SYSCALL
66 UNDEF
67 JMP 0(PC)
68
69 TEXT runtime·open(SB),NOSPLIT,$0-16
70 MOVW name+0(FP), R4
71 MOVW mode+4(FP), R5
72 MOVW perm+8(FP), R6
73 MOVW $SYS_open, R2
74 SYSCALL
75 BEQ R7, 2(PC)
76 MOVW $-1, R2
77 MOVW R2, ret+12(FP)
78 RET
79
80 TEXT runtime·closefd(SB),NOSPLIT,$0-8
81 MOVW fd+0(FP), R4
82 MOVW $SYS_close, R2
83 SYSCALL
84 BEQ R7, 2(PC)
85 MOVW $-1, R2
86 MOVW R2, ret+4(FP)
87 RET
88
89 TEXT runtime·write1(SB),NOSPLIT,$0-16
90 MOVW fd+0(FP), R4
91 MOVW p+4(FP), R5
92 MOVW n+8(FP), R6
93 MOVW $SYS_write, R2
94 SYSCALL
95 BEQ R7, 2(PC)
96 SUBU R2, R0, R2 // caller expects negative errno
97 MOVW R2, ret+12(FP)
98 RET
99
100 TEXT runtime·read(SB),NOSPLIT,$0-16
101 MOVW fd+0(FP), R4
102 MOVW p+4(FP), R5
103 MOVW n+8(FP), R6
104 MOVW $SYS_read, R2
105 SYSCALL
106 BEQ R7, 2(PC)
107 SUBU R2, R0, R2 // caller expects negative errno
108 MOVW R2, ret+12(FP)
109 RET
110
111 // func pipe2(flags int32) (r, w int32, errno int32)
112 TEXT runtime·pipe2(SB),NOSPLIT,$0-16
113 MOVW $r+4(FP), R4
114 MOVW flags+0(FP), R5
115 MOVW $SYS_pipe2, R2
116 SYSCALL
117 BEQ R7, 2(PC)
118 SUBU R2, R0, R2 // caller expects negative errno
119 MOVW R2, errno+12(FP)
120 RET
121
122 TEXT runtime·usleep(SB),NOSPLIT,$28-4
123 MOVW usec+0(FP), R3
124 MOVW R3, R5
125 MOVW $1000000, R4
126 DIVU R4, R3
127 MOVW LO, R3
128 MOVW R3, 24(R29)
129 MOVW $1000, R4
130 MULU R3, R4
131 MOVW LO, R4
132 SUBU R4, R5
133 MOVW R5, 28(R29)
134
135 // nanosleep(&ts, 0)
136 ADDU $24, R29, R4
137 MOVW $0, R5
138 MOVW $SYS_nanosleep, R2
139 SYSCALL
140 RET
141
142 TEXT runtime·gettid(SB),NOSPLIT,$0-4
143 MOVW $SYS_gettid, R2
144 SYSCALL
145 MOVW R2, ret+0(FP)
146 RET
147
148 TEXT runtime·raise(SB),NOSPLIT,$0-4
149 MOVW $SYS_getpid, R2
150 SYSCALL
151 MOVW R2, R16
152 MOVW $SYS_gettid, R2
153 SYSCALL
154 MOVW R2, R5 // arg 2 tid
155 MOVW R16, R4 // arg 1 pid
156 MOVW sig+0(FP), R6 // arg 3
157 MOVW $SYS_tgkill, R2
158 SYSCALL
159 RET
160
161 TEXT runtime·raiseproc(SB),NOSPLIT,$0
162 MOVW $SYS_getpid, R2
163 SYSCALL
164 MOVW R2, R4 // arg 1 pid
165 MOVW sig+0(FP), R5 // arg 2
166 MOVW $SYS_kill, R2
167 SYSCALL
168 RET
169
170 TEXT ·getpid(SB),NOSPLIT,$0-4
171 MOVW $SYS_getpid, R2
172 SYSCALL
173 MOVW R2, ret+0(FP)
174 RET
175
176 TEXT ·tgkill(SB),NOSPLIT,$0-12
177 MOVW tgid+0(FP), R4
178 MOVW tid+4(FP), R5
179 MOVW sig+8(FP), R6
180 MOVW $SYS_tgkill, R2
181 SYSCALL
182 RET
183
184 TEXT runtime·setitimer(SB),NOSPLIT,$0-12
185 MOVW mode+0(FP), R4
186 MOVW new+4(FP), R5
187 MOVW old+8(FP), R6
188 MOVW $SYS_setitimer, R2
189 SYSCALL
190 RET
191
192 TEXT runtime·timer_create(SB),NOSPLIT,$0-16
193 MOVW clockid+0(FP), R4
194 MOVW sevp+4(FP), R5
195 MOVW timerid+8(FP), R6
196 MOVW $SYS_timer_create, R2
197 SYSCALL
198 MOVW R2, ret+12(FP)
199 RET
200
201 // Linux: kernel/time/posix-timer.c, requiring COMPAT_32BIT_TIME
202 TEXT runtime·timer_settime32(SB),NOSPLIT,$0-20
203 MOVW timerid+0(FP), R4
204 MOVW flags+4(FP), R5
205 MOVW new+8(FP), R6
206 MOVW old+12(FP), R7
207 MOVW $SYS_timer_settime, R2
208 SYSCALL
209 MOVW R2, ret+16(FP)
210 RET
211
212 TEXT runtime·timer_settime64(SB),NOSPLIT,$0-20
213 MOVW timerid+0(FP), R4
214 MOVW flags+4(FP), R5
215 MOVW new+8(FP), R6
216 MOVW old+12(FP), R7
217 MOVW $SYS_timer_settime64, R2
218 SYSCALL
219 MOVW R2, ret+16(FP)
220 RET
221
222 TEXT runtime·timer_delete(SB),NOSPLIT,$0-8
223 MOVW timerid+0(FP), R4
224 MOVW $SYS_timer_delete, R2
225 SYSCALL
226 MOVW R2, ret+4(FP)
227 RET
228
229 TEXT runtime·mincore(SB),NOSPLIT,$0-16
230 MOVW addr+0(FP), R4
231 MOVW n+4(FP), R5
232 MOVW dst+8(FP), R6
233 MOVW $SYS_mincore, R2
234 SYSCALL
235 SUBU R2, R0, R2 // caller expects negative errno
236 MOVW R2, ret+12(FP)
237 RET
238
239 // func walltime() (sec int64, nsec int32)
240 TEXT runtime·walltime(SB),NOSPLIT,$8-12
241 MOVW $0, R4 // CLOCK_REALTIME
242 MOVW $4(R29), R5
243 MOVW $SYS_clock_gettime, R2
244 SYSCALL
245 MOVW 4(R29), R3 // sec
246 MOVW 8(R29), R5 // nsec
247 MOVW $sec+0(FP), R6
248 #ifdef GOARCH_mips
249 MOVW R3, 4(R6)
250 MOVW R0, 0(R6)
251 #else
252 MOVW R3, 0(R6)
253 MOVW R0, 4(R6)
254 #endif
255 MOVW R5, nsec+8(FP)
256 RET
257
258 TEXT runtime·nanotime1(SB),NOSPLIT,$8-8
259 MOVW $1, R4 // CLOCK_MONOTONIC
260 MOVW $4(R29), R5
261 MOVW $SYS_clock_gettime, R2
262 SYSCALL
263 MOVW 4(R29), R3 // sec
264 MOVW 8(R29), R5 // nsec
265 // sec is in R3, nsec in R5
266 // return nsec in R3
267 MOVW $1000000000, R4
268 MULU R4, R3
269 MOVW LO, R3
270 ADDU R5, R3
271 SGTU R5, R3, R4
272 MOVW $ret+0(FP), R6
273 #ifdef GOARCH_mips
274 MOVW R3, 4(R6)
275 #else
276 MOVW R3, 0(R6)
277 #endif
278 MOVW HI, R3
279 ADDU R4, R3
280 #ifdef GOARCH_mips
281 MOVW R3, 0(R6)
282 #else
283 MOVW R3, 4(R6)
284 #endif
285 RET
286
287 TEXT runtime·rtsigprocmask(SB),NOSPLIT,$0-16
288 MOVW how+0(FP), R4
289 MOVW new+4(FP), R5
290 MOVW old+8(FP), R6
291 MOVW size+12(FP), R7
292 MOVW $SYS_rt_sigprocmask, R2
293 SYSCALL
294 BEQ R7, 2(PC)
295 UNDEF // crash
296 RET
297
298 TEXT runtime·rt_sigaction(SB),NOSPLIT,$0-20
299 MOVW sig+0(FP), R4
300 MOVW new+4(FP), R5
301 MOVW old+8(FP), R6
302 MOVW size+12(FP), R7
303 MOVW $SYS_rt_sigaction, R2
304 SYSCALL
305 BEQ R7, 2(PC)
306 SUBU R2, R0, R2 // caller expects negative errno
307 MOVW R2, ret+16(FP)
308 RET
309
310 TEXT runtime·sigfwd(SB),NOSPLIT,$0-16
311 MOVW sig+4(FP), R4
312 MOVW info+8(FP), R5
313 MOVW ctx+12(FP), R6
314 MOVW fn+0(FP), R25
315 MOVW R29, R22
316 SUBU $16, R29
317 AND $~7, R29 // shadow space for 4 args aligned to 8 bytes as per O32 ABI
318 JAL (R25)
319 MOVW R22, R29
320 RET
321
322 TEXT runtime·sigtramp(SB),NOSPLIT|TOPFRAME,$12
323 // this might be called in external code context,
324 // where g is not set.
325 MOVB runtime·iscgo(SB), R1
326 BEQ R1, 2(PC)
327 JAL runtime·load_g(SB)
328
329 MOVW R4, 4(R29)
330 MOVW R5, 8(R29)
331 MOVW R6, 12(R29)
332 MOVW $runtime·sigtrampgo(SB), R1
333 JAL (R1)
334 RET
335
336 TEXT runtime·cgoSigtramp(SB),NOSPLIT,$0
337 JMP runtime·sigtramp(SB)
338
339 TEXT runtime·mmap(SB),NOSPLIT,$20-32
340 MOVW addr+0(FP), R4
341 MOVW n+4(FP), R5
342 MOVW prot+8(FP), R6
343 MOVW flags+12(FP), R7
344 MOVW fd+16(FP), R8
345 MOVW off+20(FP), R9
346 MOVW R8, 16(R29)
347 MOVW R9, 20(R29)
348
349 MOVW $SYS_mmap, R2
350 SYSCALL
351 BEQ R7, ok
352 MOVW $0, p+24(FP)
353 MOVW R2, err+28(FP)
354 RET
355 ok:
356 MOVW R2, p+24(FP)
357 MOVW $0, err+28(FP)
358 RET
359
360 TEXT runtime·munmap(SB),NOSPLIT,$0-8
361 MOVW addr+0(FP), R4
362 MOVW n+4(FP), R5
363 MOVW $SYS_munmap, R2
364 SYSCALL
365 BEQ R7, 2(PC)
366 UNDEF // crash
367 RET
368
369 TEXT runtime·madvise(SB),NOSPLIT,$0-16
370 MOVW addr+0(FP), R4
371 MOVW n+4(FP), R5
372 MOVW flags+8(FP), R6
373 MOVW $SYS_madvise, R2
374 SYSCALL
375 MOVW R2, ret+12(FP)
376 RET
377
378 // Linux: kernel/futex/syscalls.c, requiring COMPAT_32BIT_TIME
379 // int32 futex(int32 *uaddr, int32 op, int32 val,
380 // struct old_timespec32 *timeout, int32 *uaddr2, int32 val2);
381 TEXT runtime·futex_time32(SB),NOSPLIT,$20-28
382 MOVW addr+0(FP), R4
383 MOVW op+4(FP), R5
384 MOVW val+8(FP), R6
385 MOVW ts+12(FP), R7
386
387 MOVW addr2+16(FP), R8
388 MOVW val3+20(FP), R9
389
390 MOVW R8, 16(R29)
391 MOVW R9, 20(R29)
392
393 MOVW $SYS_futex, R2
394 SYSCALL
395 BEQ R7, 2(PC)
396 SUBU R2, R0, R2 // caller expects negative errno
397 MOVW R2, ret+24(FP)
398 RET
399
400 // Linux: kernel/futex/syscalls.c
401 // int32 futex(int32 *uaddr, int32 op, int32 val,
402 // struct timespec *timeout, int32 *uaddr2, int32 val2);
403 TEXT runtime·futex_time64(SB),NOSPLIT,$20-28
404 MOVW addr+0(FP), R4
405 MOVW op+4(FP), R5
406 MOVW val+8(FP), R6
407 MOVW ts+12(FP), R7
408
409 MOVW addr2+16(FP), R8
410 MOVW val3+20(FP), R9
411
412 MOVW R8, 16(R29)
413 MOVW R9, 20(R29)
414
415 MOVW $SYS_futex_time64, R2
416 SYSCALL
417 BEQ R7, 2(PC)
418 SUBU R2, R0, R2 // caller expects negative errno
419 MOVW R2, ret+24(FP)
420 RET
421
422 // int32 clone(int32 flags, void *stk, M *mp, G *gp, void (*fn)(void));
423 TEXT runtime·clone(SB),NOSPLIT|NOFRAME,$0-24
424 MOVW flags+0(FP), R4
425 MOVW stk+4(FP), R5
426 MOVW R0, R6 // ptid
427 MOVW R0, R7 // tls
428
429 // O32 syscall handler unconditionally copies arguments 5-8 from stack,
430 // even for syscalls with less than 8 arguments. Reserve 32 bytes of new
431 // stack so that any syscall invoked immediately in the new thread won't fail.
432 ADD $-32, R5
433
434 // Copy mp, gp, fn off parent stack for use by child.
435 MOVW mp+8(FP), R16
436 MOVW gp+12(FP), R17
437 MOVW fn+16(FP), R18
438
439 MOVW $1234, R1
440
441 MOVW R16, 0(R5)
442 MOVW R17, 4(R5)
443 MOVW R18, 8(R5)
444
445 MOVW R1, 12(R5)
446
447 MOVW $SYS_clone, R2
448 SYSCALL
449 BEQ R7, 2(PC)
450 SUBU R2, R0, R2 // caller expects negative errno
451
452 // In parent, return.
453 BEQ R2, 3(PC)
454 MOVW R2, ret+20(FP)
455 RET
456
457 // In child, on new stack.
458 // Check that SP is as we expect
459 NOP R29 // tell vet R29/SP changed - stop checking offsets
460 MOVW 12(R29), R16
461 MOVW $1234, R1
462 BEQ R16, R1, 2(PC)
463 MOVW (R0), R0
464
465 // Initialize m->procid to Linux tid
466 MOVW $SYS_gettid, R2
467 SYSCALL
468
469 MOVW 0(R29), R16 // m
470 MOVW 4(R29), R17 // g
471 MOVW 8(R29), R18 // fn
472
473 BEQ R16, nog
474 BEQ R17, nog
475
476 MOVW R2, m_procid(R16)
477
478 // In child, set up new stack
479 MOVW R16, g_m(R17)
480 MOVW R17, g
481
482 // TODO(mips32): doesn't have runtime·stackcheck(SB)
483
484 nog:
485 // Call fn
486 ADDU $32, R29
487 JAL (R18)
488
489 // It shouldn't return. If it does, exit that thread.
490 ADDU $-32, R29
491 MOVW $0xf4, R4
492 MOVW $SYS_exit, R2
493 SYSCALL
494 UNDEF
495
496 TEXT runtime·sigaltstack(SB),NOSPLIT,$0
497 MOVW new+0(FP), R4
498 MOVW old+4(FP), R5
499 MOVW $SYS_sigaltstack, R2
500 SYSCALL
501 BEQ R7, 2(PC)
502 UNDEF // crash
503 RET
504
505 TEXT runtime·osyield(SB),NOSPLIT,$0
506 MOVW $SYS_sched_yield, R2
507 SYSCALL
508 RET
509
510 TEXT runtime·sched_getaffinity(SB),NOSPLIT,$0-16
511 MOVW pid+0(FP), R4
512 MOVW len+4(FP), R5
513 MOVW buf+8(FP), R6
514 MOVW $SYS_sched_getaffinity, R2
515 SYSCALL
516 BEQ R7, 2(PC)
517 SUBU R2, R0, R2 // caller expects negative errno
518 MOVW R2, ret+12(FP)
519 RET
520
521 // func sbrk0() uintptr
522 TEXT runtime·sbrk0(SB),NOSPLIT,$0-4
523 // Implemented as brk(NULL).
524 MOVW $0, R4
525 MOVW $SYS_brk, R2
526 SYSCALL
527 MOVW R2, ret+0(FP)
528 RET
529
530 TEXT runtime·access(SB),$0-12
531 BREAK // unimplemented, only needed for android; declared in stubs_linux.go
532 MOVW R0, ret+8(FP) // for vet
533 RET
534
535 TEXT runtime·connect(SB),$0-16
536 BREAK // unimplemented, only needed for android; declared in stubs_linux.go
537 MOVW R0, ret+12(FP) // for vet
538 RET
539
540 TEXT runtime·socket(SB),$0-16
541 BREAK // unimplemented, only needed for android; declared in stubs_linux.go
542 MOVW R0, ret+12(FP) // for vet
543 RET
544
View as plain text